Динамическое создание объектов Delphi 6

Динамическое создание кнопки Button на форме.

Для того чтобы посмотреть как работает динамическое создание объектов н форме Delphi 6 Вы можете создать новый проект, затем разместить на неё кнопку Button1 и поле ввода Edit1 затем просто заменить код проекта на тот что я предлагаю в листинге ниже.

В данном примере динамическая кнопка создаётся по событию клика на кнопку Button1. Для хранения объекта динамической кнопки я использую переменную dinBut: TButton; которая описана в var. В начале процедуры клика по кнопке Button1, которая изначально создана на форме, я описал условие защиты от повторного создания динамической кнопки, а именно строку if (dinBut = nil) then. Работает она следующим образом, пока метод TButton.Create не вызван переменная dinBut равна nil. Если она равна nil то только в этом случаи выполняется основное тело процедуры клика по кнопке Button то есть создание динамической кнопки. Иначе полю ввода Edit1 будет присвоен текст "Не создан(попытка повторного создания)". В процессе работы программы описанной в листинге Вы увидите такое сообщение в Edit1 после второго клика по кнопке Button1.

Создания события клика по динамической кнопке производится строкой dinBut.OnClick:=myDinButClick; то есть присваивается процедура которая в листинге начинается с строки procedure TForm1.myDinButClick(Sender: TObject);. Эту процедуру так же необходимо добавить в { Public declarations } в type.

Удалить динамический объект можно строкой кода FreeAndNil(dinBut); в листинге строка закомментирована, поскольку нет смысла удалять только что созданный объект. Вы можете создать ещё одну кнопку в которой разместить данную строку для того чтобы посмотреть как работает удаление динамических объектов.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    procedure myDinButClick (Sender: TObject);
    { Public declarations }
  end;

var
  Form1: TForm1;
  dinBut: TButton;

implementation

{$R *.dfm}

procedure TForm1.myDinButClick(Sender: TObject);
begin
  Form1.Edit1.Text:= 'Результат нажатия динамической кнопки';
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  if (dinBut = nil) then//Защита от повторного создания(проверяем создан ли объект)
  begin
    dinBut:= TButton.Create(Form1);
    dinBut.Parent:=Form1;//Родитель Form1
    dinBut.Left:=80;//Отступ на форме слева
    dinBut.Top:=80;//Отступ на форме вверху
    dinBut.Caption:='Динамически созданная кнопка';
    dinBut.Width:=200;//Длина 200
    dinBut.Height:=30;//Высота 30
    //FreeAndNil(dinBut);//Так удалять динамический объект
    dinBut.OnClick:=myDinButClick;//Присвоение поцедуры по событию клика
  end else begin//При попытке повторного создания выведем сообщение в Edit1
    Edit1.Text:= 'Не создан(попытка повторного создания)';
  end;
end;

end.

Динамическое создание ClientSocket

Переместите на форму кнопку Button1 и многострочное поле ввода Memo1 после чего замените код проекта на тот что приведен в листинге.

unit Unit1;
      
interface
      
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ScktComp;
      
type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    procedure myDinClientSocketError(Sender: TObject; Socket: TCustomWinSocket; ErrorEvent: TErrorEvent; var ErrorCode: Integer);
    procedure myDinClientSocketDisconnect(Sender: TObject; Socket: TCustomWinSocket);
    procedure myDinClientSocketConnect(Sender: TObject; Socket: TCustomWinSocket);
    procedure myDinClientSocketRead(Sender: TObject; Socket: TCustomWinSocket);
    procedure myDinClientSocketWrite(Sender: TObject; Socket: TCustomWinSocket);
    { Public declarations }
  end;
      
var
  Form1: TForm1;
  dinClientSocket:TClientSocket;
      
implementation
      
{$R *.dfm}
      
procedure TForm1.myDinClientSocketRead(Sender: TObject;
  Socket: TCustomWinSocket);
begin
//В случаи длинной HTML страницы информация может поступать частями
//поэтому используем Memo1.Lines.Add а не Memo1.Text:=поскольку иначе
//в мемо будет отображаться только последний фрагмент полученный сокетом
  Memo1.Lines.Add('------');//Обозначаем место начала фрагмента
  Memo1.Lines.Add(Socket.ReceiveText());
end;
      
procedure TForm1.myDinClientSocketWrite(Sender: TObject;
  Socket: TCustomWinSocket);
begin
//В следующей строке запрашиваем у Web серера HTML код страницы /?id=1
  Socket.SendText('GET /?id=1 HTTP/1.1'+#13+#10+'Host: blog.ivru.net'+#13+#10+
  'User-Agent: Delphi 6 (program by nikolaevevge)'+#13+#10+#13+#10);//Сообщение которое означает что это клиент LongProxy
end;
      
procedure TForm1.myDinClientSocketError(Sender: TObject;
  Socket: TCustomWinSocket; ErrorEvent: TErrorEvent;
  var ErrorCode: Integer);
begin
  Socket.Close;
  ErrorCode:=0;
  //Дополнительные действия
end;
      
procedure TForm1.myDinClientSocketDisconnect(Sender: TObject;
  Socket: TCustomWinSocket);
begin
  //Ничего не делаем
end;
      
procedure TForm1.myDinClientSocketConnect(Sender: TObject;
  Socket: TCustomWinSocket);
begin
  //Ничего не делаем
end;
      
procedure TForm1.Button1Click(Sender: TObject);
begin
  if (dinClientSocket = nil) then
  begin
    dinClientSocket:=TClientSocket.Create(Form1);//Создаём
    dinClientSocket.Host:= 'blog.ivru.net';//Указываем хост для соединения
    dinClientSocket.Port:= 80;//Указываем порт для соединения
      
//Следующие 5 строчек присвоение процедур к событиям
    dinClientSocket.OnError:= myDinClientSocketError;
    dinClientSocket.OnDisconnect:= myDinClientSocketDisconnect;
    dinClientSocket.OnConnect:= myDinClientSocketConnect;
    dinClientSocket.OnRead:= myDinClientSocketRead;
    dinClientSocket.OnWrite:= myDinClientSocketWrite;
      
    dinClientSocket.Active:= true;//Активируем соединение
  end;
end;
      
end.

Динамическое создание кнопки Button на форме.

Динамическое создание ClientSocket

Комментарии